Membuat Dan Membaca Data INI File (.ini) di VB

Membuat Dan Menulis Data Pada INI File (.ini)  di VB.
Dan kali ini saya akan membahas bagaimana cara menyimpan suatu informasi dalam file Text dengan format INI file (*.ini).

File ini dapat anda gunakan untuk menyimpan pengaturan sebuah aplikasi, misalnya sebagai media penyimpanan sementara untuk sebuah data konfigurasi database. Pada percobaan ini saya menggunakan database MySQL, tentunya disana terdapat beberapa variable seperti Server, Database,User, Port, dan Password. Trik atau cara ini saya aplikasikan di Aplikasi Perpustakaan pada menu backup restore data

Agar lebih mudah dalam menyimpan dan membaca informasi pada INI file membutuhkan 2 fungsi WinAPI, Apa itu WinAPI? Silahkan mampir dulu kesini untuk mengetahui apa itu WinAPI :D.

Sebagai contoh buatlah 2 buah form. form pertama untuk membuat atau menyimpan INI file dan form kedua untuk menampilkan atau membaca data INI file. Formnya seperti gambar berikut ini

Tampilkan Gambar

Form1 Membuat INI File (.ini)

Form2 Menampilkan Data INI File (.ini)

 Kemudian tambahkan sebuah modul dengan cara klik menu Project - Add Modul kemudian ketiklah atau copy pastekan 2 kode WinAPI berikut ini pada modul

Option Explicit
Public Declare Function WritePrivateProfileString& Lib "kernel32" _
    Alias "WritePrivateProfileStringA" (ByVal AppName$, ByVal KeyName$, _
    ByVal keydefault$, ByVal FileName$)
    
Public Declare Function GetPrivateProfileString& Lib "kernel32" _
    Alias "GetPrivateProfileStringA" (ByVal AppName$, ByVal KeyName$, _
    ByVal keydefault$, ByVal ReturnedString$, ByVal RSSize&, ByVal FileName$)

kemudian ketiklah / copy pastekan kode berikut ini di bawak kode di atas ini berfungsi untuk menulis data di dalam file ini

'prosedure untuk menulis file ini
Public Sub WriteINI(INISection As String, INIKey As String, _
    INIValue As String, INIFile As String)
    
    Call WritePrivateProfileString(INISection, INIKey, INIValue, INIFile)
End Sub

Kemudian ketikan / copy pastekan lagi kode berikut ini, berfungsi untuk membaca atau menampilkan data dari file INI yang telah dibuat.

'prosedure untuk membaca file ini
Public Function ReadINI(INISection As String, INIKey As String, _
    INIFile As String) As String
  
    Dim StringBuffer As String
    Dim StringBufferSize As Long
    
    StringBuffer = Space$(255)
    StringBufferSize = Len(StringBuffer)
    
    StringBufferSize = GetPrivateProfileString(INISection, INIKey, "", _
        StringBuffer, StringBufferSize, INIFile)
    
    If StringBufferSize > 0 Then
        ReadINI = Left$(StringBuffer, StringBufferSize)
    Else
        ReadINI = ""
    End If
End Function

Bagaimana caranya mengetahui fungsi WinAPI selain 2 yang tadi?
Caranya seperti ini
1. Klik Add-Ins -> Add-Ins Manager
2. Pilih VB6 API Viewer -> Centang Loaded/Unloaded dan centang juga Load On StartUp -> Klik OK
3. Pilih Add-Ins -> API Viewer
4. Pada Jendela API Viewer pilih File -> Load Text File -> Pilih Win32API.txt -> Open
5. Semua daftar fungsi WinAPI sudah ditampilkan. jika anda ingin menambahkannya ke dalam form/module, pilih terlebih dahulu fungsi WinAPI yang akan digunakan kemudian Klik Add, Setelah itu Klik Copy atau Klik Insert.

Kembali ketopik semula buka form1 double klik pada tombol simpan lalu ketikan copy pastekan koding berikut ini

Call WriteINI("SETTING", "Server", txtServer.Text, (App.Path & "\konfig.ini"))
Call WriteINI("SETTING", "Database", txtDatabase.Text, (App.Path & "\konfig.ini"))
Call WriteINI("SETTING", "Port", txtPort.Text, (App.Path & "\konfig.ini"))
Call WriteINI("SETTING", "User", txtUser.Text, (App.Path & "\konfig.ini"))
Call WriteINI("SETTING", "Password", txtPassword.Text, (App.Path & "\konfig.ini"))
MsgBox "Your File INI was saved!"

kemudian double klik tombol tampilkan dan ketiklah copy pastekan koding berikut ini

Form2.Show 1

Kemudian di form dua pada bagian form load silahkan koding beriktu ini

txtServer.Text = (ReadINI("SETTING", "Server", App.Path & "\konfig.ini"))
txtDatabase.Text = (ReadINI("SETTING", "Database", App.Path & "\konfig.ini"))
txtPort.Text = (ReadINI("SETTING", "Port", App.Path & "\konfig.ini"))
txtUser.Text = (ReadINI("SETTING", "User", App.Path & "\konfig.ini"))
txtPassword.Text = (ReadINI("SETTING", "Password", App.Path & "\konfig.ini"))

Jika sudah semua silahkan simpan dan jalankan.Demikian tutorial ini semoga dapat bermanfaat. Jika ada yang kurang mengerti silahkan kasih komentar.
Jika anda ingin source codenya silahkan download di link di bawah ini

DOWNLOAD

Jika berhasil maka akan seperti gambar animasi berikut ini

Membuat Dan Membaca Data INI File (.ini)  di VB

Keyword:

Membuat Dan membaca Data INI File (.ini)  di VB,Menyimpan Dan menampilkan Data  INI File (.ini)  di VB,Cara Menyimpan Dan menampilkan Data  INI File (.ini)  di VB,Menulis Dan Membaca Data  INI File (.ini)  di VB